焦点宏
属于多条件判定宏，这个宏是使用非常多的，因此单拉出来。
直接上一个德鲁伊旋风的吧，大家根据自己需要自行修好就好了。
#showtooltip 
/cast [mod,@focus,exists,harm][@mouseover,exists,harm][]旋风
 
移动能量条宏，敌对精灵火/友善净化腐蚀宏，隐遁回春/偷袭宏，回春潜行宏，一键保命宏，回春急奔宏，熊/猫技能整合宏，焦点与当前目标互换宏，同层天赋显示宏，生活技能整合宏
移动能量条，通过系统自带功能，实现能量条的移动，然后将其与TMW等监视插件丢在合适的位置，会舒服很多。
用宏将能量条移动至指定位置，原帖子见 [[搬运]教你如何用宏将能量条移动到屏幕中间] ，他是移动鸟德的日月能条，并指出设置方式，本人直接将设置能量条的宏放出来。而且类似圣能条，牧师的暗影宝珠都可以移动。自己参照原帖设置吧，很简单的。
本宏缺点：因为是使用系统自带的功能，所以读条重置游戏、长时间脱战等很多情况都会致使能量条复位，需要再次点击宏。可以随时打 /rl 主动复位 
第一行不管；第二行数字是坐标；第三行数字是缩放比例；第四行数字是透明度，请根据需要自行调整其中数字。
/run PlayerFrameManaBar:ClearAllPoints()
/run PlayerFrameManaBar:SetPoint("CENTER", UIParent, "CENTER", -135, -28) 
/run PlayerFrameManaBar:SetScale(1.2) 
/run PlayerFrameManaBar:SetAlpha(1.1)
敌对精灵火(优先组合键焦点目标，其次鼠标指向目标，最后敌对目标)，友善净化腐蚀宏(优先鼠标指向目标)，这个鼠标指向同时对框架中名字指向有效
#showtooltip
/cast [mod,@focus,exists,harm][@mouseover,exists,harm][harm]精灵之火;[@mouseover,exists,help][]净化腐蚀
类似的回春/月火宏，大家自行发挥。
#showtooltip
/cast [modifier:alt,target=player][@mouseover,exists,help][help] 回春术;[@mouseover,exists,harm][harm]月火术
德鲁伊分为两种，精灵德鲁依与非精灵德鲁伊，影遁作为一个种族技能，非常的逆天了，在此丢出几个影遁宏
影遁回春宏血迷迭在[[5_2猫德PVP] 新手猫德PVP经验总结及新手问题汇总]提出的，非战斗回春潜行睡觉，战斗中回春影遁睡觉，睡觉似乎可以减少一次被DOT跳出来的机率，按了影遁之后，等潜行CD好了再按一下就直接进入猫形态潜行了，这个宏就当作对影遁的加强使用吧。当然本人不喜欢这种工作方式，影遁很多时候是用来进攻的，这个是防守，很容易被打出来。同时PVP中节奏非常快，此宏战斗非战斗判断并不能替代平时的潜行宏
#showtooltip 影遁
/cast [target=player] 回春术
/cast [nocombat,nostealth]潜行
/cast [combat,nostealth] 影遁
/stopattack
/睡觉
影遁偷袭宏本人使用的隐遁宏绑定了偷袭，虽然隐遁后可以直接偷袭，但是很多时候目标不在偷袭攻击距离内，需要略微移动一段距离，所以还是绑定潜行更稳妥。针对需要隐遁跑路的情况，离开敌人近战AOE范围，直接点击宏，因为攻击距离的问题，无法偷袭成功，后面是直接跑开或者变鸟都不影响(前提是不能插偷袭雕文，否则13码偷袭太暴力了)
#showtooltip 
/cast 影遁
/targetenemyplayer [noharm]
/cast !潜行
/cast [stealth] 突袭
回春潜行宏：潜行不占用共CD，所以可以在潜行前面加上回春术，猫开启化身期间也可以使用，回春必然变人，同时加上/cancelform语句，对操作不产生影响；而且在豹子吃冰冻陷阱后，猎人想接恐惧野兽，再点击一次就变人打断猎人读条了。对于平时的读条恐惧野兽，直接点击宏，会变人套回春的，宏缺点为浪费一个共CD套回春，但也带来一个回春HOT的收益，个人非常喜欢此宏。(绑定了鼠标指向回春，怕浪费回春HOT，直接鼠标放在团队框架队友名字上即可，这个回春就会丢给队友了)
#showtooltip 回春术
/cast 狂暴回复
/cancelform 
/cast [@mouseover,exists,help][]回春术
/cast !潜行
号称移动速度第一的德鲁伊，必须匹配下面这个宏了，一键变形跑路宏
#showtooltip 旅行形态 
/cast 狂暴回复
/cast [swimming]!水栖形态;[indoors]!猎豹形态;[flyable,nocombat]!迅捷飞行形态;!旅行形态 
/script UIErrorsFrame:Clear()
熊/猫一键保命宏，绑定了一个回春，因此不能抽筋去点，不然会变人形态的，实在是改不了习惯，就把回春这一行取消好了。
#showtooltip 乌索克之力
/cast 狂暴回复
/cast [target=player]回春术
/use 恶孽角斗士的顽强纹章
/cast 乌索克之力
/use 治疗石
/cast 新生
/cast 树皮术
/p 山寨破斧已开，注意刷血
/ra 山寨破斧已开，注意刷血
/in15 /p /ra 山寨破斧5秒后消失，将大量掉血
急奔回春宏再丢一个保命宏，因为急奔不占用公CD，也可以和回春绑定，由吖花提供。但是本人不喜好这个宏，对于熊/猫来讲，急奔多用于解定身并节约一个共CD去输出使用，此宏用于鸟/树可能性居多
#showtooltip 急奔
/cast 狂暴回复
/cast [target=player] 回春术
/cast 急奔
熊/猫技能整合宏。专用宏一18个，很有有必要的。根据需要自行修改/增加技能及条件
#showtooltip 
/cast [modifier:alt,stance:3]横扫;[stance:3]撕碎
/cast [stance:1,modifier:alt,@mouseover,exists,harm][stance:1,modifier:alt]低吼;[stance:1]割伤
#showtooltip 
/cast [mod:shift,@mouseover,exists,harm][mod:shift,harm]纠缠根须;[mod:alt,stance:3]横扫;[stance:3]突袭;[mod:alt,stance:1,@mouseover,exists,help][mod:alt,stance:1]回春术;[stance:1]裂伤;[nostance:1/3]回春术
#showtooltip 
/cast [mod:shift,@focus,exists,harm]纠缠根须;[mod:alt,stance:3]痛击;[stance:3]斜掠;[mod:alt,stance:1]低吼;[stance:1]痛击;[mod:alt,nostance:1/3,@focus,exists,harm][nostance:1/3]安抚
#showtooltip 
/cast [mod:shift,@mouseover,exists,harm][mod:shift,harm]休眠;[mod:alt,stance:3]凶猛撕咬;[stance:3]割裂;[mod:alt,stance:1]激怒;[stance:1]横扫;[nostance:1/3]激活
焦点与当前目标互换宏，22里用的最多，开局设置焦点，然后死命打，中途需要转火焦点时，直接点击就好了，立马缓过来了。但是目前盗贼消失、猎人假死、牧师幽灵伪装、法师镜像等大量清焦点技能，使用此宏须灵活。以此宏为原型，可以演变出不少其他的用途，自行发挥吧。
/cleartarget [target=target, dead]
/clearfocus [target=focus, dead]
/target focus
/cleartarget [target=focus, noexists]
/targetlasttarget
/focus target
/targetlasttarget
更改天赋后，使用下述的2个宏，可以实现同层天赋显示宏，第一个简短些，第二个据说显示的效果好一些
#showtooltip 
/use 新生 
/use 塞纳里奥结界 
/use 伊瑟拉之赐 
/run SetMacroSpell("宏的名称", GetSpellInfo ("新生") or GetSpellInfo ("塞纳里奥结界") or "伊瑟拉之赐")
#showtooltip 
/use 新生 
/use 塞纳里奥结界 
/use 伊瑟拉之赐 
/run local g,m,f=GetSpellInfo;m=function()SetMacroSpell("宏的名字",g("新生")or g("塞纳里奥结界")or g("伊瑟拉之赐"))end f=TgS or CreateFrame("Frame","TgS")f:SetScript("OnEvent",m)f:RegisterEvent("SPELLS_CHANGED")m()
生活技能整合宏已经过期了，但是很经典，根据需要自己修改吧。
左键钓鱼、右键炉石；alt加左键锻造、alt加右键工程；ctrl加左键急救、ctrl加右键考古；shift加左键烹饪、shift加右键烧火。可自行更改技能。
#showtooltip 
/use [nomod,btn:1]钓鱼;[nomod,btn:2]炉石 
/use [mod:alt,btn:1]锻造;[mod:alt,btn:2]工程学 
/use [mod:ctrl,btn:1]急救;[mod:ctrl,btn:2]考古学 
/use [mod:shift,btn:1]烹饪;[mod:shift,btn:2]烹饪用火